logo

Query di esempio

Una sezione di esempi relativa ai dati del Catalogo generale dei beni culturali, si trova anche qui: Esempi di query sul Catalogo (queries del team ISTC-CNR, StLab)

* * * * *

“Luoghi della cultura” con i seguenti dati: Nome Istituzionale, Descrizione, Identifier, Latitudine, Longitudine, Tipo, luogo, Disciplina, Indirizzo, Codice postale, Comune, Provincia, Prenotazioni, Orari di apertura, Telefono, Fax, Email, WebSite, Biglietti,  Servizi

La paginazione si ottiene variando il parametro offset [in fondo] con multipli della paginazione. Ad aprile 2018 con pagine di 10000 i dati si esauriscono con 7 richieste

select * where {

 select distinct ?s as ?subject

 ?Nome_Istituzionale
 ?Descrizione
 ?Identifier
 ?Latitudine
 ?Longitudine
 ?Disciplina
 ?Indirizzo
 ?Codice_postale
 ?Comune
 ?Provincia
 ?Prenotazioni
 ?Orari_di_apertura
 ?Telefono
 ?Fax
 ?Email
 ?WebSite
 str(?Biglietti) as ?Biglietti
 ?Servizi

 where {

  graph <http://dati.beniculturali.it/mibact/luoghi> {

   ?s rdf:type cis:CulturalInstituteOrSite ;
      cis:institutionalCISName ?Nome_Istituzionale .
   optional { ?s l0:description ?Descrizione }
   optional { ?s l0:identifier ?Identifier }
   optional { ?s geo:lat ?Latitudine }
   optional { ?s geo:long ?Longitudine }
   optional { ?s cis:hasDiscipline [l0:name ?Disciplina] }
   optional {
    ?s cis:hasSite [cis:siteAddress ?address ] .
    optional { ?address clvapit:fullAddress ?Indirizzo }
    optional { ?address clvapit:postCode ?Codice_postale }
    optional { ?address clvapit:hasCity [rdfs:label ?Comune] }
    optional { ?address clvapit:hasProvince [rdfs:label ?Provincia] }
   }
   optional {?s accessCondition:hasAccessCondition [rdf:type accessCondition:Booking ;
                                                    rdfs:label ?Prenotazioni] }
   optional {?s accessCondition:hasAccessCondition [rdf:type accessCondition:OpeningHoursSpecification ;
                                                    l0:description ?Orari_di_apertura ] }
   optional {
    ?s smapit:hasOnlineContactPoint ?contactPoint .
    optional { ?contactPoint smapit:hasTelephone [smapit:hasTelephoneType <https://w3id.org/italia/controlled-vocabulary/classifications-for-public-services/channel/031> ;
                                                  smapit:telephoneNumber ?Telefono] }
    optional { ?contactPoint smapit:hasTelephone [smapit:hasTelephoneType <https://w3id.org/italia/controlled-vocabulary/classifications-for-public-services/channel/033> ;
                                                  smapit:telephoneNumber ?Fax] }
    optional { ?contactPoint smapit:hasEmail [smapit:emailAddress ?Email] }
    optional { ?contactPoint smapit:hasWebSite [smapit:URL ?WebSite] }    
   }   
   optional {
    ?s potapit:hasTicket ?ticket .
    ?offer potapit:includes ?ticket ;
           potapit:hasPriceSpecification [potapit:hasCurrencyValue ?Biglietti]
   }
   optional { ?s cis:providesService [l0:name ?Servizi] }
  }
 }
 order by ?s

}
limit 100
offset 0

Esegui la query


Archivi della Lombardia

SELECT ?s ?nome ?provincia 
WHERE {
 ?s rdf:type cis:HolderOfArchive .
 ?s rdfs:label ?nome .
 ?s cis:hasSite ?location .
 ?location cis:hasAddress ?location2 .
 ?location2 cis:adminUnitL2 ?provincia .
 FILTER( (?provincia= "Milano") || 
 (?provincia= "Brescia") || 
 (?provincia= "Bergamo") || 
 (?provincia= "Como") || 
 (?provincia= "Cremona") || 
 (?provincia= "Lecco") || 
 (?provincia= "Lodi") ||
 (?provincia= "Pavia") ||
 (?provincia= "Mantova") ||
 (?provincia= "Sondrio") || 
 (?provincia= "Varese") || 
 (?provincia= "Monza e della Brianza"))
}
ORDER BY ?provincia
LIMIT 100

Esegui la query


L’Archivio di Stato di Torino

SELECT ?p ?o
WHERE {
 ?s ?p ?o .
 FILTER (?s=<http://dati.beniculturali.it/icar/san/CulturalInstituteOrSite/Archivio_di_Stato_di_Torino>)
}

Esequi la query


Le schede di catalogo relative a beni del territorio del Comune di Bologna

SELECT ?scheda ?fascicolo ?titolo 
WHERE { 
  ?scheda rdf:type cis:CulturalHeritageObject . 
  ?scheda dc:title ?titolo . 
  ?scheda dc:identifier ?fascicolo . 
  ?scheda dct:subject ?subj . 
  ?subj cis:hasSite ?site . 
  ?site cis:hasGeographicalLocation ?location . 
  ?location rdfs:label ?luogo . 
  FILTER (?luogo= "Comune di BOLOGNA"@it) 
} 
ORDER BY ?fascicolo
LIMIT 100

Esegui la query


Gli eventi culturali, con indicazione della sede, indirizzo e Comune (ordinati per nome)

SELECT DISTINCT ?evento ?sede ?indirizzo ?comune
WHERE {
  ?x a cis:CulturalEvent ;
    rdfs:label ?evento ;
    cis:isHostedBySite ?site .
  ?site cis:siteAddress ?address .
  ?address clvapit:hasCity [rdfs:label ?comune] .
  ?address clvapit:fullAddress ?indirizzo .
  ?y cis:hasSite ?site ; 
     rdfs:label ?sede .
 } 
ORDER BY ?evento
LIMIT 100

Esegui la query


I luoghi della cultura, con indirizzo e Comune (ordinati per nome)

SELECT DISTINCT ?luogo ?indirizzo ?comune
WHERE {
 ?x a cis:CulturalInstituteOrSite ;
  cis:institutionalCISName ?luogo ;
  cis:hasSite ?site .
 ?site cis:siteAddress ?address .
 ?address clvapit:fullAddress ?indirizzo ;
          clvapit:hasCity [rdfs:label ?comune] .
} 
ORDER BY ?luogo
LIMIT 100

Esegui la query


I luoghi della cultura allineati con i dati della Regione Emilia-Romagna

SELECT * WHERE {
  ?s owl:sameAs ?p .
  FILTER regex(str(?p), "http://dati.emilia-romagna.it/", "i")
}
LIMIT 100

Esegui la query


I contenitori fisici allineati con i luoghi della cultura

SELECT ?s AS ?luoghi_della_cultura ?o AS ?contenitori_fisici 
WHERE {
  GRAPH <http://dati.beniculturali.it/silk-enti-LuoghiCult2CF> {
    ?s ?p ?o
  }
}
LIMIT 100

Esegui la query


Conta i luoghi della cultura (solo dati del DBUnico)

select COUNT(?s) AS ?count where {
 graph <http://dati.beniculturali.it/mibact/luoghi> {
  ?s rdf:type cis:CulturalInstituteOrSite 
 }
}

Esegui la query


Il numero di triple RDF presenti nell’endpoint

SELECT (COUNT(*) as ?triple) WHERE { ?s ?p ?o }

Esegui la query


I record degli archivi fotografici, in formato tabellare

La paginazione si ottiene variando il parametro offset [in fondo] con multipli della paginazione
(query di Fabio Domenico Alberto Ginestrini, 3D Endless)

prefix ac: <https://w3id.org/arco/core/>
prefix al: <https://w3id.org/arco/location/>
prefix dd: <https://w3id.org/arco/denotative-description/>
prefix cd: <https://w3id.org/arco/context-description/>
prefix ti: <https://w3id.org/italia/onto/TI/>
select distinct ?s ?id ?titolo ?autoreFotografia ?luogoRipresa ?crono ?type ?format ?medium
 ?subject ?transcript ?nrInventario ?notizieStoricoCritiche ?categoria ?filetype ?rights ?archivio ?dataRipresa
 ?u1 ?u2 ?u3 ?u4 ?u5 ?u6 where{graph <http://dati.beniculturali.it/iccd/fotografico>{
 ?s rdf:type ac:PhotographicHeritage ;
    cd:isMemberOfCollection [cd:hasCollection [rdfs:label "Archivio MPI (Ministero della Pubblica Istruzione)"]] ;
    ac:localIdentifier ?id ;
    rdfs:label ?titolo ;
    cd:hasSubject [rdfs:label ?subject] ;
    ac:localIdentifier ?nrInventario .
 optional{?s al:hasTimeIndexedQualifiedLocation ?tl .
  ?tl al:hasLocationType al:ShotLocation ; al:atLocation [skos:altLabel ?luogoRipresa] .
  optional{?tl ti:atTime [ti:Time ?dataRipresa]}}  
 optional{?s dd:hasDating [cd:hasEvent [ti:atTime [rdfs:label ?crono]]]}
 optional{?s dd:hasTechnicalDetailOccurrence ?tdf . ?tdf dd:satisfiesTechnicalDetail [rdfs:label ?format] filter(contains(str(?tdf),"photo-size"))}
 optional{?s dd:hasTechnicalDetailOccurrence ?tdm . ?tdm dd:satisfiesTechnicalDetail [rdfs:label ?medium] filter(contains(str(?tdm),"material-technique"))}
 optional{?s dd:hasCulturalPropertyType [rdfs:label ?type]}
 optional{?s ac:hasAuthor [rdfs:label ?autoreFotografia]}
 optional{?s dd:hasAffixedElement [ac:description ?transcript]}
 optional{?s ac:description ?notizieStoricoCritiche}
 optional{?s ac:hasCategory [rdfs:label ?categoria]}
 optional{?s  cis:isMemberOfColCultEnt ?ua . ?ua rdfs:label ?ual
  optional{?ua cis:isMemberOfColCultEnt ?ub . ?ub rdfs:label ?ubl
   optional{?ub cis:isMemberOfColCultEnt ?uc . ?uc rdfs:label ?ucl
    optional{?uc cis:isMemberOfColCultEnt ?ud . ?ud rdfs:label ?udl
     optional{?ud cis:isMemberOfColCultEnt ?ue . ?ue rdfs:label ?uel
      optional{?ue cis:isMemberOfColCultEnt ?uf . ?uf rdfs:label ?ufl}}}}}}
 bind(if(bound(?ufl),?ufl,if(bound(?uel),?uel,if(bound(?udl),?udl,if(bound(?ucl),?ucl,if(bound(?ubl),?ubl,?ual))))) as ?u1)
 bind(if(bound(?ufl),?uel,if(bound(?uel),?udl,if(bound(?udl),?ucl,if(bound(?ucl),?ubl,if(bound(?ubl),?ual,?ubl))))) as ?u2)
 bind(if(bound(?ufl),?udl,if(bound(?uel),?ucl,if(bound(?udl),?ubl,if(bound(?ucl),?ual,?ucl)))) as ?u3)
 bind(if(bound(?ufl),?ucl,if(bound(?uel),?ubl,if(bound(?udl),?ual,?udl))) as ?u4)
 bind(if(bound(?ufl),?ubl,if(bound(?uel),?ual,?uel)) as ?u5)
 bind(if(bound(?ufl),?ual,?ufl) as ?u6)
 bind("immagine" as ?filetype)
 bind("CC-Y-SA-NC 4.0" as ?rights)
 bind("ICCD-GFN" as ?archivio)
}}
LIMIT 100
OFFSET 0

Esegui la query


Il numero di beni culturali catalogati nel Catalogo generale dei beni culturali e pubblicati

select count (distinct ?s) as ?count where {
 ?s <https://w3id.org/arco/ontology/catalogue/catalogueRecordIdentifier> ?x
}

Esegui la query