logo

Query federate

Le opere d’arte descritte nei dati della Fondazione Federico Zeri conservate nei Luoghi della cultura

select distinct * where {
  ?s a cis:Museum;
     owl:sameAs ?actor;
     rdfs:label ?label .
  SERVICE <http://data.fondazionezeri.unibo.it/sparql> {
    ?analogItem crm:P50_has_current_keeper ?actor;
                foaf:depiction ?depiction .
  }
}
LIMIT 100

Esegui la query


Le opere d’arte descritte su Wikipedia conservate nei Luoghi della cultura

select distinct ?museumBc str(?museum) as ?museo ?artworkDbp where {

 ?museumBc a cis:Museum ;
           rdfs:label ?museum ;
           owl:sameAs ?museumDbp .

 FILTER (contains(str(?museumDbp),"dbpedia.org"))
 FILTER (!contains(str(?museumDbp),"'"))

 SERVICE <http://it.dbpedia.org/sparql> {

  ?artworkDbp dbo:location ?museumDbp ;
              rdf:type dbo:Artwork .
 }
}
ORDER BY ?museum
LIMIT 100

Esegui la query


I dati dei Contenitori fisici rappresentati in base ai comuni per percentuale di consumo di suolo nel 2012 (indicatore C4 sui dati ISPRA)

select distinct str(?cfl) as ?contenitoreFisico str(?percentage) as ?consumo str(?comune) as ?comune str(?provincia) as ?provincia where {

 ?cf dc:type "contenitore fisico ICCD" ;
     cis:hasSite ?cfS ;
     cis:institutionalCISName ?cfl .
 ?cfS cis:siteAddress ?cfA .
 ?cfA clvapit:hasProvince [rdfs:label ?provincia] ;
      clvapit:hasCity ?cfC .
 ?cfC owl:sameAs ?ispraGF ;
      rdfs:label ?comune .

 FILTER (contains(str(?ispraGF),"dati.isprambiente.it"))

 SERVICE <http://dati.isprambiente.it/sparql> {
  ?ispraIC foaf:primaryTopic ?ispraGF ;
           rdf:type <http://dati.isprambiente.it/ontology/core#IndicatorCollection> .
  ?indicator <http://purl.org/dc/terms/type> <http://dati.isprambiente.it/id/skos/sc/C4> ; 
             dc:date "2012" ; 
             <http://purl.org/dc/terms/isPartOf> ?ispraIC ; 
             <http://www.w3.org/1999/02/22-rdf-syntax-ns#value> ?percentage . 
 }
}
ORDER BY DESC(xsd:float(?percentage) )
LIMIT 100

Esegui la query


Le opere presenti nelle Biblioteche aderenti al Coordinamento Biblioteche Speciali e Specialistiche di Torino (CoBiS)

select distinct * where {

 ?cis_id a cis:Library ;
         rdfs:label ?cis_library ;
         owl:sameAs ?cobis_id .

 SERVICE <https://dati.cobis.to.it/sparql> {

  ?cobis_id <http://dati.cobis.to.it/vocab/documentDesc> ?documenti ;
            rdfs:label ?cobis_library ;
            <http://schema.org/description> ?descrizione .
 
 }
}
ORDER BY ?cis_library
LIMIT 100

Esegui la query